Architettura della Conoscenza


Guida


ArCo è il Knowledge Graph del patrimonio culturale italiano, e comprende: una rete di 7 vocabolari che descrivono il dominio dei beni culturali e i dati estratti dal Catalogo Generale dei Beni Culturali dell'ICCD-MiBAC e trasformati in RDF, in accordo con le ontologie.

Questo documento descrive brevemente le ontologie incluse nella versione v1.0 di ArCo, una rete di ontologie per descrivere i diversi tipi di beni culturali e le schede catalografiche ad essi associate, gestite con il sistema SIGEC dall'Istituto Centrale per il Catalogo e la Documentazione.

Fare riferimento a questo documento per la guida alla versione 0.1, a questo documento per la guida alla versione 0.2, a questo documento per la guida alla versione 0.3, a questo documento per la versione 0.4, a questo documento per la versione 0.5.

Ontologie


Dati


Il dataset di ArCo può essere scaricato in formato N-Triples in un unico dump compresso.

Usa lo SPARQL endpoint del progetto ArCo per interrogare i dati interattivamente.

Esempi (SPARQL)


Quali eventi culturali hanno interessato il bene culturale X?

Quali sono le persone coinvolte nelle operazioni di redazione e aggiornamento della scheda sul bene culturale X, e con quali ruoli?

Quando è stata redatta e aggiornata la scheda sul bene culturale X?

PREFIX l0: <https://w3id.org/italia/onto/l0/>
PREFIX cis: <http://dati.beniculturali.it/cis/>
SELECT ?event ?eventName ?culturalProperty ?culturalPropertyLabel
WHERE{
  ?event cis:involvesCulturalEntity ?culturalProperty ;
    l0:name ?eventName .
  ?culturalProperty rdfs:label ?culturalPropertyLabel
}
limit 100
PREFIX arco-catalogue: <https://w3id.org/arco/ontology/catalogue/>
PREFIX roapit: <https://w3id.org/italia/onto/RO/>
SELECT *
WHERE{
  ?entity arco-catalogue:hasCatalogueRecordVersion ?record . 
  ?record arco-catalogue:hasCatalogueRecordVersionRiT ?rit . 
  ?rit roapit:withRole ?role ;
    roapit:isRoleInTimeOf ?agent
}
limit 100
PREFIX arco-catalogue: <https://w3id.org/arco/ontology/catalogue/>
SELECT *
WHERE{
  ?record arco-catalogue:hasCatalogueRecordVersion ?recordVersion . 
  ?recordVersion arco-catalogue:editedAtTime ?time .
  ?time rdfs:label ?timeLabel
}
limit 100

Quali sono tutte le localizzazioni in contenitori fisici che hanno riguardato il bene culturale X e di che tipo sono?

Quali sono i luoghi che hanno rivestito la funzione di deposito nei confronti di un certo bene culturale?

Qual è lo stato di conservazione del bene culturale X? E quali interventi sul bene sono stati proposti?

PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
    arco-location:hasTimeIndexedTypedLocation ?location .
  ?location arco-location:hasLocationType ?locationType ;
    arco-location:atSite ?site .
}
limit 100
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
SELECT *
WHERE {
  ?entity rdfs:label ?entityLabel ; 
    arco-location:hasTimeIndexedTypedLocation ?location .
  ?location arco-location:hasLocationType arco-location:StorageLocation.
}
limit 100
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT ?entity ?entityLabel ?conservation ?proposedIntervention
WHERE{
  ?entity rdfs:label ?entityLabel ;
    arco-dd:proposedIntervention ?proposedIntervention ;
    arco-dd:hasConservationStatus ?conservation .
}
LIMIT 100

Qual è la documentazione fotografica allegata alla scheda del bene culturale X?

Qual è il codice univoco associato al bene culturale X?

Quali sono tutti gli autori o gli ambiti culturali attribuiti al bene culturale X? E con quale ruolo? E quale motivazione giustifica l'attribuzione?

PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT ?entity ?documentation
WHERE{
  
 ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; arco-cd:hasDocumentation ?documentation .
  ?documentation a arco-cd:PhotographicDocumentation 


}
limit 100
PREFIX arco-arco: <https://w3id.org/arco/core/>
SELECT ?entity ?id
WHERE{
  ?entity arco-arco:uniqueIdentifier ?id 
}
limit 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity arco-cd:hasAuthorshipAttribution ?attribution .
  ?attribution arco-cd:hasInterventionRole ?role ;
    arco-cd:hasInterpretationCriterion ?criterion
}
limit 100

A quando risale la realizzazione del bene culturale X? E quale motivazione giustifica la cronologia?

Quali sono le coordinate geografiche del bene culturale X?

Quali sono gli usi del bene culturale mobile X?

PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
SELECT *
WHERE{?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ;
    rdfs:label ?entityLabel ;
  arco-cd:hasDating ?dating .
  ?dating arco-cd:hasDatingEvent ?event ;
  arco-cd:hasInterpretationCriterion ?criterion.
}
limit 100
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>
SELECT *
WHERE{
  ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ;
  clvapit:hasGeometry ?geometry .
  ?geometry arco-location:hasCoordinates ?coordinates .

}
limit 100
PREFIX arco: <https://w3id.org/arco/ontology/arco/>
PREFIX context: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity a arco:MovableCulturalProperty ;
  rdfs:label ?entityLabel ;
  context:hasUse ?use .

}
limit 100

Quali sono i proprietari precedenti del bene culturale X?

Quali sono le entità che rappresentano le fasi preparatorie del bene culturale X?

Quali sono i beni culturali costruiti con l'argilla?

PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
  arco-cd:hasAcquisition ?acquisition .
  ?acquisition arco-cd:hasPreviousOwner ?previousOwner .

}

limit 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
  arco-cd:hasRelatedWorkSituation ?relatedWorkSituation .
  ?relatedWorkSituation arco-cd:involvesRelatedWork ?relatedWork .
  ?relatedWork a arco-cd:PreparatoryWork .

}

Limit 100
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
SELECT ?entity ?clay
WHERE{

{?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; 
  arco-dd:hasTechnicalStatus ?techstatus. 
  ?techstatus arco-dd:includesTechnicalCharacteristic ?clay.
  FILTER regex(?clay, "argilla", "i")}

UNION

{?entity a arco-arco:CulturalProperty ;
  arco-dd:hasMaterial ?clay.
  FILTER regex(?clay, "argilla", "i")}

}

Allineamento della CulturalPropertyDefinition dei reperti archeologici con il thesaurus per la definizione del bene (scheda RA)

Quali sono le ricognizioni archeologiche effettuate sul bene culturale X?

In quale posizione (es.: frontespizio, copertina, etc.) di una specifica pubblicazione è stata riprodotta la stampa X?

PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT DISTINCT *
WHERE{
 ?definition rdf:type arco-dd:CulturalPropertyDefinition ;
 skos:closeMatch ?alignment
}
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT DISTINCT *
WHERE{
 ?cultProp arco-cd:hasSurvey ?survey . ?survey rdf:type arco-cd:ArchaeologicalFieldSurvey .
 
}
LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT ?title ?reproduction ?position
WHERE {?publication arco-cd:hasTitle ?pubtitle .
?pubtitle rdfs:label ?title .
?publication arco-cd:hasReproduction ?reproduction .
?reproduction arco-cd:hasReproductionPosition ?position }
LIMIT 100

Su quale supporto si trova l'iscrizione del bene X?

Quanti beni culturali di tipo "chiesa" ci sono nella regione Emilia-Romagna?

Quali beni fanno parte della collezione X?

PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT *
WHERE {
 ?cultpro arco-dd:hasAffixedElement ?elem.
 ?elem a arco-dd:Inscription.
 ?elem arco-dd:hasSupport ?supp
} LIMIT 100
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
PREFIX CLV: <https://w3id.org/italia/onto/CLV/>
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT  (count(distinct ?cultpro) as ?count)
WHERE {
 ?cultpro a arco-arco:ArchitecturalOrLandscapeHeritage.
 ?cultpro arco-location:hasCulturalPropertyAddress ?address.
 ?address CLV:hasRegion ?region.
 ?region rdfs:label ?regNome.
 ?cultpro arco-dd:hasCulturalPropertyType ?type.
 ?type arco-dd:hasCulturalPropertyDefinition ?def
 FILTER regex(?regNome, "Emilia-Romagna", "i")
 FILTER regex(?def, "chiesa", "i") } 
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX cis: <http://dati.beniculturali.it/cis/>
SELECT ?collection ?item
WHERE {
 ?collection a cis:CollectionCulEnt.
 ?collection arco-cd:isCollectionIn ?collectionmemb.
 ?collectionmemb arco-cd:hasMemberOfCollection ?item.
} LIMIT 100

Quali sono le dimensioni della fotografia X?

Quali beni hanno come soggetto la Sfinge?

What are the licenses, privileges, authorizations of the cultural property X?

PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description>
PREFIX muapit: <https://w3id.org/italia/onto/MU/>
SELECT ?photo ?meastype ?value ?unit
WHERE {
 ?photo a arco-arco:PhotographicHeritage.
  ?photo arco-dd:hasMeasurementCollection ?meascoll .
  ?meascoll arco-dd:hasMeasurement ?meas .
  ?meas arco-dd:hasMeasurementType ?meastype . 
  ?meas arco-dd:hasValue ?measvalue .
  ?measvalue muapit:value ?value .
  ?measvalue muapit:hasMeasurementUnit ?unit } LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/> 
SELECT *

WHERE {
?cultpro rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; arco-cd:hasSubject ?sub .
?sub rdfs:label ?label
FILTER(REGEX(STR(?label), "sfinge", "i"))} LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
SELECT *
WHERE {
 ?cultpro rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; arco-cd:rights ?right .
} LIMIT 100