Architecture of Knowledge


Guide


ArCo is the knowledge Graph of the Italian Cultural Heritage: it consists of 13 vocabularies describing the cultural heritage domain and data from the General Catalogue of the Italian Ministry of Cultural Heritage (MiC) published as RDF.

This document briefly describes the ontologies part of the version 2.0 of ArCo. The ontologies are organised in a network for modelling different kind of cultural properties and their corresponding catalog records. Those cultural properties and records are currently managed by the SIGEC system of the Italian Central Institute for Cataloguing and Documentation.

Use this document (English version) for the guide of the version 0.5. Use this document (Italian only) for the guide associated with the version 0.1, this document (Italian only) for the guide of the version 0.2, this document (Italian only) for the guide of the version 0.3, this document (Italian only) for the guide of the version 0.4. Use this document for the guide of version 1.0.

Ontologie


Data


The ArCo dataset can be downloaded as a single N-Triples compressed dump.

Use the SPARQL endpoint of the ArCo project to query data interactively.

Examples (SPARQL)


What are the cultural events related to the cultural property X?

Who are the people involved in the editing and the updating of the catalogue record describing the cultural property X? What are their roles?

When was the catalogue record about the cultural property X edited or updated?

                PREFIX l0: <https://w3id.org/italia/onto/l0/>
                PREFIX cis: <http://dati.beniculturali.it/cis/>
                SELECT ?event ?eventName ?culturalProperty ?culturalPropertyLabel
                WHERE{
                  ?event cis:involvesCulturalEntity ?culturalProperty ;
                    l0:name ?eventName .
                  ?culturalProperty rdfs:label ?culturalPropertyLabel
                }
                limit 100
PREFIX arco-catalogue: <https://w3id.org/arco/ontology/catalogue/>
PREFIX core: <https://w3id.org/arco/ontology/core/>
SELECT *
WHERE{
  ?entity arco-catalogue:hasRecordVersion ?record . 
  ?record core:hasAgentRole ?agentRole . 
  ?agentRole core:hasRole ?role ;
    core:hasAgent ?agent
}
limit 100
PREFIX arco-catalogue: <https://w3id.org/arco/ontology/catalogue/>
SELECT *
WHERE{
  ?record arco-catalogue:hasRecordVersion ?recordVersion . 
  ?recordVersion arco-catalogue:editedAtTime ?time .
  ?time rdfs:label ?timeLabel .
}
limit 100

What are all the locations in cultural sites associated with the cultural property X? What are their types?

What are the places that have been used as storage location for a cultural property?

What is the conservation status of the cultural property X? Which interventions have been proposed?

PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
    arco-location:hasTimeIndexedTypedLocation ?location .
  ?location arco-location:hasLocationType ?locationType ;
    arco-location:atSite ?site .
}
limit 100
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
SELECT *
WHERE {
  ?entity rdfs:label ?entityLabel ; 
    arco-location:hasTimeIndexedTypedLocation ?location .
    ?location arco-location:hasLocationType arco-location:StorageLocation .
  }
limit 100
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT ?entity ?entityLabel ?conservationType ?proposedIntervention
WHERE{
  ?entity rdfs:label ?entityLabel ;
    arco-cd:proposedIntervention ?proposedIntervention ;
    arco-dd:hasConservationStatus ?conservation .
  ?conservation core:hasType ?conservationType. 
}
LIMIT 100

What is the photographic documentation attached to the catalogue record describing the cultural property X?

What is the unique identifier of the cultural property X?

Who are the authors and what are the cultural scopes attributed to the cultural property X? What is their role? What is the source of the attribution?

PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT ?entity ?documentation
WHERE{
  ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; 
    arco-cd:hasAttachedDocumentation ?documentation .
  ?documentation a arco-cd:PhotographicDocumentation .
}
limit 100
                PREFIX arco-core: <https://w3id.org/arco/core/>
                SELECT ?entity ?id
                WHERE{
                  ?entity core:hasIdentifier ?identifier.
                  ?identifier core:hasType core:UniqueIdentifier ;
                    core:identifier ?id .
                }
                limit 100
                
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity arco-cd:hasResponsibility ?responsibility .
  ?responsibility arco-cd:hasInterventionRole ?role ;
    arco-cd:informationSource ?source .
}
limit 100

When was the cultural property X realised? What is the source of the dating?

What are the geographical coordinates of the cultural property X?

What are the uses associated to the movable cultural property X?

                PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
                PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
                PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
                SELECT *
                WHERE{
                  ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ;
                    rdfs:label ?entityLabel ;
                    arco-cd:hasDating ?dating .
                  ?dating arco-cd:hasDatingEvent ?event ;
                    arco-cd:informationSource ?source .
                  ?event rdfs:label ?eventLabel 
                FILTER regex(?eventLabel, "realizzazione", "i")
                }
                  limit 100
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>
SELECT *
WHERE{
  ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ;
  clvapit:hasGeometry ?geometry .
  ?geometry arco-location:hasCoordinates ?coordinates .

}
limit 100
PREFIX arco: <https://w3id.org/arco/ontology/arco/>
PREFIX context: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity a arco:MovableCulturalProperty ;
  rdfs:label ?entityLabel ;
  context:hasUse ?use .

}
limit 100

Who was the previous owner of the cultural property X?

What are the entities that represent the preparatory phases for the cultural property X?

What are the cultural properties made of clay?

PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX core: <https://w3id.org/arco/ontology/core/>
PREFIX resource: <https://w3id.org/arco/resource/Role/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
    arco-cd:hasLegalSituation ?legalSituation .
  ?legalSituation core:hasAgentRole ?agentRole .
  ?agentRole core:hasRole resource:PreviousOwner ;
    core:hasAgent ?agent .
}
limit 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT *
WHERE{
  ?entity rdfs:label ?entityLabel ;
  arco-cd:hasRelatedWorkSituation ?relatedWorkSituation .
  ?relatedWorkSituation arco-cd:involvesRelatedWork ?relatedWork .
  ?relatedWork a arco-cd:PreparatoryWork .

}

Limit 100
                PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
                PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
                PREFIX arco-lite: <https://w3id.org/arco/ontology/arco-lite/>
                SELECT ?entity ?clay
                WHERE{
                
                { ?entity rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; 
                    arco-dd:hasTechnicalStatus ?techstatus. 
                  ?techstatus arco-dd:includesTechnicalCharacteristic ?clay.
                  FILTER regex(?clay, "argilla", "i")}
                
                UNION
                
                { ?entity a arco-arco:CulturalProperty ;
                    arco-lite:hasMaterial ?clay.
                  FILTER regex(?clay, "argilla", "i")}
                
                }
                

Alignment of the CulturalPropertyDefinition with the thesaurus used for providing definitions of the cultural properties (RA catalogue record type).

What are the archaeological field surveys on the cultural property X?

In which position (eg: title page, cover, etc.) of a specific publication was the X print reproduced?

PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
SELECT DISTINCT *
WHERE{
 ?definition rdf:type arco-dd:CulturalPropertyDefinition ;
 skos:closeMatch ?alignment .
}
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT DISTINCT *
WHERE{
  ?cultProp arco-cd:hasSurvey ?survey . 
  ?survey rdf:type arco-cd:ArchaeologicalFieldSurvey .
}
LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
SELECT ?title ?reproduction ?position
WHERE {?publication arco-cd:hasTitle ?pubtitle .
?pubtitle rdfs:label ?title .
?publication arco-cd:hasReproduction ?reproduction .
?reproduction arco-cd:hasReproductionPosition ?position .
}
LIMIT 100

On what support is the iscription of the cultural property X?

How many cultural entities of the "church" type are located in Emilia-Romagna?

What cultural properties are members of the collection X?

PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
PREFIX core: <https://w3id.org/arco/ontology/core/>
SELECT *
WHERE {
  ?cultpro arco-dd:hasAffixedElement ?elem.
  ?elem core:hasType arco-dd:Inscription.
  ?elem arco-dd:hasSupport ?supp .
} 
LIMIT 100
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-location: <https://w3id.org/arco/ontology/location/>
PREFIX CLV: <https://w3id.org/italia/onto/CLV/>
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description/>
PREFIX arco-lite: <https://w3id.org/arco/ontology/arco-lite/>
SELECT  (count(distinct ?cultpro) as ?count)
WHERE {
  ?cultpro a arco-arco:ArchitecturalOrLandscapeHeritage.
  ?cultpro arco-lite:hasCulturalPropertyAddress ?address.
  ?address CLV:hasRegion ?region.
  ?region rdfs:label ?regNome.
  ?cultpro arco-dd:hasCulturalPropertyType ?type.
  ?type arco-dd:hasCulturalPropertyDefinition ?def .
  FILTER regex(?regNome, "Emilia-Romagna", "i")
  FILTER regex(?def, "chiesa", "i") 
}
                PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
                PREFIX cis: <http://dati.beniculturali.it/cis/>
                PREFIX arco-lite: <https://w3id.org/arco/ontology/arco-lite/>
                SELECT ?collection ?item
                WHERE {
                  ?collection a cis:CollectionCulEnt.
                  ?collection arco-lite:hasCollectionMember ?item .
                } 
                LIMIT 100
                

What are the dimensions of photography X?

What cultural properties have the Sphinx as their subject?

In which position (eg: title page, cover, etc.) of a specific publication was the X print reproduced?

PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
PREFIX arco-dd: <https://w3id.org/arco/ontology/denotative-description>
PREFIX muapit: <https://w3id.org/italia/onto/MU/>
SELECT ?photo ?meastype ?value ?unit
WHERE {
 ?photo a arco-arco:PhotographicHeritage.
  ?photo arco-dd:hasMeasurementCollection ?meascoll .
  ?meascoll arco-dd:hasMeasurement ?meas .
  ?meas arco-dd:hasMeasurementType ?meastype . 
  ?meas arco-dd:hasValue ?measvalue ;
    muapit:hasMeasurementUnit ?unit .
  ?measvalue muapit:value ?value .
} 
LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/> 
PREFIX arco-lite: <https://w3id.org/arco/ontology/arco-lite/> 
SELECT *
WHERE {
  ?cultpro rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; arco-lite:hasCulturalPropertySubject ?sub .
  ?sub rdfs:label ?label .
  FILTER(REGEX(STR(?label), "sfinge", "i"))
} 
LIMIT 100
PREFIX arco-cd: <https://w3id.org/arco/ontology/context-description/>
PREFIX arco-arco: <https://w3id.org/arco/ontology/arco/>
SELECT *
WHERE {
  ?cultpro rdf:type/rdfs:subClassOf* arco-arco:CulturalProperty ; 
    arco-cd:hasCopyright ?right .
  ?right arco-cd:specifications ?spec .
} 
LIMIT 100